(整)注册表进行操作的函数(2)
’接上(1)
注册表进行操作的函数(2)
‘————————————————————————————————————-
‘- 获得已存在的注册表关键字的值…
‘- 如果 ValueName="" 则返回 KeyName 项的默认值…
‘- 如果指定的注册表关键字不存在, 则返回空串…
‘- 参数说明: KeyRoot–根类型, KeyName–子项名称, ValueName–值项名称, ValueType–值项类型
‘————————————————————————————————————-
Public Function GetKeyValue(KeyRoot As KeyRoot, KeyName As String, ValueName As String, Optional ValueType As Long) As String
Dim TempValue As String ‘ 注册表关键字的临时值
Dim Value As String ‘ 注册表关键字的值
Dim ValueSize As Long ‘ 注册表关键字的值的实际长度
TempValue = Space(1024) ‘ 存储注册表关键字的临时值的缓冲区
ValueSize = 1024 ‘ 设置注册表关键字的值的默认长度
‘ 打开一个已存在的注册表关键字…
RegOpenKeyEx KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey
‘ 获得已打开的注册表关键字的值…
RegQueryValueEx hKey, ValueName, 0, ValueType, ByVal TempValue, ValueSize
‘ 返回注册表关键字的的值…
Select Case ValueType ‘ 通过判断关键字的类型, 进行处理
Case REG_SZ, REG_MULTI_SZ, REG_EXPAND_SZ
TempValue = Left$(TempValue, ValueSize - 1) ‘ 去掉TempValue尾部空格
Value = TempValue
Case REG_DWORD
ReDim dValue(3) As Byte
RegQueryValueEx hKey, ValueName, 0, REG_DWORD, dValue(0), ValueSize
For i = 3 To 0 Step -1
Value = Value + String(2 - Len(Hex(dValue(i))), "0") + Hex(dValue(i)) ‘ 生成长度为8的十六进制字符串
Next i
If CDbl("&H" & Value) < 0 Then ‘ 将十六进制的 Value 转换为十进制
Value = 2 ^ 32 + CDbl("&H" & Value)
Else
Value = CDbl("&H" & Value)
End If
Case REG_BINARY
If ValueSize > 0 Then
ReDim bValue(ValueSize - 1) As Byte ‘ 存储 REG_BINARY 值的临时数组
RegQueryValueEx hKey, ValueName, 0, REG_BINARY, bValue(0), ValueSize
For i = 0 To ValueSize - 1
Value = Value + String(2 - Len(Hex(bValue(i))), "0") + Hex(bValue(i)) + " " ‘ 将数组转换成字符串
Next i
End If
End Select
‘ 关闭注册表关键字…
RegCloseKey hKey
GetKeyValue = Trim(Value) ‘ 返回函数值
End Function
‘————————————————————————————————————-
‘- 删除已存在的注册表关键字的值…
‘- 如果指定的注册表关键字不存在, 则不做任何操作…
‘- 参数说明: KeyRoot–根类型, KeyName–子项名称, ValueName–值项名称
‘————————————————————————————————————-
Public Function DeleteKey(KeyRoot As KeyRoot, KeyName As String, Optional ValueName As String) As Boolean
Dim tmpKeyName As String ‘ 注册表关键字的临时子项名称
Dim tmpValueName As String ‘ 注册表关键字的临时子键名称
‘ 打开一个已存在的注册表关键字…
Success = RegOpenKeyEx(KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey)
If Success <> ERROR_SUCCESS Then DeleteKey = False: RegCloseKey hKey: Exit Function
‘ 删除已打开的注册表关键字…
tmpKeyName = ""
tmpValueName = KeyName
If ValueName = "" Then ‘ 判断ValueName是否缺省, 如缺省作相应处理
If InStrRev(KeyName, "\") > 1 Then
tmpValueName = Right(KeyName, InStrRev(KeyName, "\") + 1)
tmpKeyName = Left(KeyName, InStrRev(KeyName, "\") - 1)
End If
Success = RegOpenKeyEx(KeyRoot, tmpKeyName, 0, KEY_ALL_ACCESS, hKey)
Success = RegDeleteKey(hKey, tmpValueName)
Else
Success = RegDeleteValue(hKey, ValueName)
End If
If Success <> ERROR_SUCCESS Then DeleteKey = False: RegCloseKey hKey: Exit Function
‘ 关闭注册表关键字…
RegCloseKey hKey
DeleteKey = True ‘ 返回函数值
End Function
‘————————————————————————————————————-
‘- 获得注册表关键字的一些信息…
‘- SubKeyName() 注册表关键字的所有子项的名称(注意:最小下标为0)
‘- ValueName() 注册表关键字的所有子键的名称(注意:最小下标为0)
‘- ValueType() 注册表关键字的所有子键的类型(注意:最小下标为0)
‘- CountKey 注册表关键字的子项数量
‘- CountValue 注册表关键字的子键数量
‘- MaxLenKey 注册表关键字的子项名称的最大长度
‘- MaxLenValue 注册表关键字的子键名称的最大长度
‘————————————————————————————————————-
Public Function GetKeyInfo(KeyRoot As KeyRoot, KeyName As String, SubKeyName() As String, ValueName() As String, ValueType() As ValueType, Optional CountKey As Long, Optional CountValue As Long, Optional MaxLenKey As Long, Optional MaxLenValue As Long) As Boolean
Dim f As FILETIME
Dim l As Long, s As String, t As ValueType
‘ 打开一个已存在的注册表关键字…
Success = RegOpenKeyEx(KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey)
If Success <> ERROR_SUCCESS Then GetKeyInfo = False: RegCloseKey hKey: Exit Function
‘ 获得一个已打开的注册表关键字的信息…
Success = RegQueryInfoKey(hKey, vbNullString, ByVal 0&, ByVal 0&, CountKey, MaxLenKey, ByVal 0&, CountValue, MaxLenValue, ByVal 0&, ByVal 0&, f)
If Success <> ERROR_SUCCESS Then GetKeyInfo = False: RegCloseKey hKey: Exit Function
If CountKey <> 0 Then
ReDim SubKeyName(CountKey - 1) As String ‘ 重新定义数组, 使用数组大小与注册表关键字的子项数量匹配
For i = 0 To CountKey - 1
SubKeyName(i) = Space(255)
l = 255
RegEnumKeyEx hKey, i, ByVal SubKeyName(i), l, 0, vbNullString, ByVal 0&, f
SubKeyName(i) = Left(SubKeyName(i), l)
Next i
‘ 下面的二重循环对字符串数组进行冒泡排序
For i = 0 To UBound(SubKeyName)
For j = i + 1 To UBound(SubKeyName)
If SubKeyName(i) > SubKeyName(j) Then
s = SubKeyName(i)
SubKeyName(i) = SubKeyName(j)
SubKeyName(j) = s
End If
Next j
Next i
End If
If CountValue <> 0 Then
ReDim ValueName(CountValue - 1) As String ‘ 重新定义数组, 使用数组大小与注册表关键字的子键数量匹配
ReDim ValueType(CountValue - 1) As ValueType ‘ 重新定义数组, 使用数组大小与注册表关键字的子键数量匹配
For i = 0 To CountValue - 1
ValueName(i) = Space(255)
l = 255
RegEnumValue hKey, i, ByVal ValueName(i), l, 0, ValueType(i), ByVal 0&, ByVal 0&
ValueName(i) = Left(ValueName(i), l)
Next i
‘ 下面的二重循环对字符串数组进行冒泡排序
For i = 0 To UBound(ValueName)
For j = i + 1 To UBound(ValueName)
If ValueName(i) > ValueName(j) Then
s = ValueName(i)
ValueName(i) = ValueName(j)
ValueName(j) = s
t = ValueType(i)
ValueType(i) = ValueType(j)
ValueType(j) = t
End If
Next j
Next i
End If
‘ 关闭注册表关键字…
RegCloseKey hKey
GetKeyInfo = True ‘ 返回函数值
End Function
‘————————————————————————————————————-
‘- 导出注册表关键字的值
‘- 参数说明: KeyRoot–根类型, KeyName–子项名称, FileName–导出的文件路径及文件名(原始数据库格式)
‘————————————————————————————————————-
Public Function SaveKey(KeyRoot As KeyRoot, KeyName As String, FileName As String) As Boolean
On Error Resume Next
Dim lpAttr As SECURITY_ATTRIBUTES ‘ 注册表安全类型
lpAttr.nLength = 50 ‘ 设置安全属性为缺省值…
lpAttr.lpSecurityDescriptor = 0 ‘ …
lpAttr.bInheritHandle = True ‘ …
If EnablePrivilege(SE_BACKUP_NAME) = False Then
SaveKey = False
Exit Function
End If
Success = RegOpenKeyEx(KeyRoot, KeyName, 0&, KEY_ALL_ACCESS, hKey)
If Success <> 0 Then
SaveKey = False
Success = RegCloseKey(hKey)
Exit Function
End If
Success = RegSaveKey(hKey, FileName, lpAttr)
If Success = 0 Then SaveKey = True Else SaveKey = False
Success = RegCloseKey(hKey)
End Function
‘————————————————————————————————————-
‘- 导入注册表关键字的值
‘- 参数说明: KeyRoot–根类型, KeyName–子项名称, FileName–导入的文件路径及文件名(原始数据库格式)
‘————————————————————————————————————-
Public Function RestoreKey(KeyRoot As KeyRoot, KeyName As String, FileName As String) As Boolean
On Error Resume Next
If EnablePrivilege(SE_RESTORE_NAME) = False Then
RestoreKey = False
Exit Function
End If
Success = RegOpenKeyEx(KeyRoot, KeyName, 0&, KEY_ALL_ACCESS, hKey)
If Success <> 0 Then
RestoreKey = False
Success = RegCloseKey(hKey)
Exit Function
End If
Success = RegRestoreKey(hKey, FileName, REG_FORCE_RESTORE)
If Success = 0 Then RestoreKey = True Else RestoreKey = False
Success = RegCloseKey(hKey)
End Function
‘————————————————————————————————————-
‘- 使注册表允许导入/导出
‘————————————————————————————————————-
Private Function EnablePrivilege(seName As String) As Boolean
On Error Resume Next
Dim p_lngRtn As Long
Dim p_lngToken As Long
Dim p_lngBufferLen As Long
Dim p_typLUID As LUID
Dim p_typTokenPriv As TOKEN_PRIVILEGES
Dim p_typPrevTokenPriv As TOKEN_PRIVILEGES
p_lngRtn = OpenProcessToken(GetCurrentProcess(), TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, p_lngToken)
If p_lngRtn = 0 Then
EnablePrivilege = False
Exit Function
End If
If Err.LastDllError <> 0 Then
EnablePrivilege = False
Exit Function
End If
p_lngRtn = LookupPrivilegeValue(0&, seName, p_typLUID)
If p_lngRtn = 0 Then
EnablePrivilege = False
Exit Function
End If
p_typTokenPriv.PrivilegeCount = 1
p_typTokenPriv.Privileges.Attributes = SE_PRIVILEGE_ENABLED
p_typTokenPriv.Privileges.pLuid = p_typLUID
EnablePrivilege = (AdjustTokenPrivileges(p_lngToken, False, p_typTokenPriv, Len(p_typPrevTokenPriv), p_typPrevTokenPriv, p_lngBufferLen) <> 0)
End Function
‘————————————————————————————————————-
‘- 将 Double 型( 限制在 0–2^32-1 )的数字转换为十六进制并在前面补零
‘- 参数说明: Number–要转换的 Double 型数字
‘————————————————————————————————————-
Private Function DoubleToHex(ByVal Number As Double) As String
Dim strHex As String
strHex = Space(8)
For i = 1 To 8
Select Case Number - Int(Number / 16) * 16
Case 10
Mid(strHex, 9 - i, 1) = "A"
Case 11
Mid(strHex, 9 - i, 1) = "B"
Case 12
Mid(strHex, 9 - i, 1) = "C"
Case 13
Mid(strHex, 9 - i, 1) = "D"
Case 14
Mid(strHex, 9 - i, 1) = "E"
Case 15
Mid(strHex, 9 - i, 1) = "F"
Case Else
Mid(strHex, 9 - i, 1) = CStr(Number - Int(Number / 16) * 16)
End Select
Number = Int(Number / 16)
Next i
DoubleToHex = strHex
End Function
